web-dev-qa-db-de.com

Fortschrittsbalken in MS Access

Ich habe eine Abfrage, die in Microsoft Access 2010 ausgeführt wird, und die normale Ausführung dauert mehr als 30 Minuten. Ich möchte dem Endbenutzer einen Status der Abfrage mitteilen. Ein Fortschrittsbalken wäre nett, aber nicht erforderlich. Der Zugriff scheint schlecht durchlaufen zu sein und hängt während der Ausführung der Abfrage eng zusammen, wobei alle von mir versuchten Updates verworfen werden. Während ich lieber VS auspacke und dazu meine eigene App schreibe, bin ich gezwungen, Access zu benutzen.

Irgendwelche Ideen?

EDIT

Ich habe dies aus einem Batch-Skript heraus ausgeführt, das die Datenbank ausfüllte, aber ich möchte, dass alles in Access enthalten ist. Um genau zu sein, ist die "Abfrage" eigentlich ein VBA-Skript, das eine Reihe von Hosts pingt. Es geht mir also nicht darum, die Zeit per se zu optimieren, sondern den Endbenutzer einfach wissen zu lassen, dass er nicht gesperrt ist. 

22
Menefee

Ich mache oft so etwas

Dim n As Long, db As DAO.Database, rs As DAO.Recordset

'Show the hour glass
DoCmd.Hourglass True

Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT ...")

rs.MoveLast 'Needed to get the accurate number of records

'Show the progress bar
SysCmd acSysCmdInitMeter, "working...", rs.RecordCount

rs.MoveFirst
Do Until rs.EOF
    'Do the work here ...

    'Update the progress bar
    n = n + 1
    SysCmd acSysCmdUpdateMeter, n

    'Keep the application responding (optional)
    DoEvents

    rs.MoveNext
Loop
rs.Close: Set rs = Nothing
db.Close: Set db = Nothing

'Remove the progress bar
SysCmd acSysCmdRemoveMeter

'Show the normal cursor again
DoCmd.Hourglass False

Hinweis: Natürlich müssen Sie die Arbeit programmgesteuert ausführen, damit dies funktioniert. Sie können eine laufende Abfrage in Code oder Ähnlichem in Access nicht anzeigen. Möglicherweise könnten Sie die Arbeit Ihrer langsamen Abfrage in kleinere Teile aufteilen, um die Möglichkeit zu erhalten, einen Fortschrittsbalken zu aktualisieren. Sie können aber immer die Sanduhr zeigen; Dies sagt dem Benutzer, dass etwas passiert.

Für den Fall, dass andere das für nützlich halten könnten, hier eine Klasse, die ich zu diesem Zweck geschrieben habe. Ich verwende es ständig in meinen Access-Entwicklungsprojekten. Legen Sie es einfach in Ihrem Projekt in einem Klassenmodul namens clsLblProg ab und verwenden Sie es wie folgt:

enter image description here

Dies erzeugt eine schöne kleine Fortschrittsanzeige:

enter image description here

In Ihrem Formular benötigen Sie nur drei Etiketten. Stellen Sie das rückseitige Etikett auf die gewünschte Größe ein und machen Sie die anderen beiden verborgen. Die Klasse erledigt den Rest.

enter image description here

Und hier ist der Code für clsLblProg:

Option Compare Database
Option Explicit

' By Adam Waller
' Last Modified:  12/16/05

'Private Const sngOffset As Single = 1.5    ' For Excel
Private Const sngOffset As Single = 15      ' For Access

Private mdblMax As Double   ' max value of progress bar
Private mdblVal As Double   ' current value of progress bar
Private mdblFullWidth As Double ' width of front label at 100%
Private mdblIncSize As Double
Private mblnHideCap As Boolean  ' display percent complete
Private mobjParent As Object    ' parent of back label
Private mlblBack As Access.Label     ' existing label for back
Private mlblFront As Access.Label   ' label created for front
Private mlblCaption As Access.Label ' progress bar caption
Private mdteLastUpdate As Date      ' Time last updated
Private mblnNotSmooth As Boolean    ' Display smooth bar by doevents after every update.

' This class displays a progress bar created
' from 3 labels.
' to use, just add a label to your form,
' and use this back label to position the
' progress bar.

Public Sub Initialize(BackLabel As Access.Label, FrontLabel As Access.Label, CaptionLabel As Access.Label)

    On Error GoTo 0    ' Debug Mode


    Dim objParent As Object ' could be a form or tab control
    Dim frm As Form

    Set mobjParent = BackLabel.Parent
    ' set private variables
    Set mlblBack = BackLabel
    Set mlblFront = FrontLabel
    Set mlblCaption = CaptionLabel

    ' set properties for back label
    With mlblBack
        .Visible = True
        .SpecialEffect = 2  ' sunken. Seems to lose when not visible.
    End With

    ' set properties for front label
    With mlblFront
        mdblFullWidth = mlblBack.Width - (sngOffset * 2)
        .Left = mlblBack.Left + sngOffset
        .Top = mlblBack.Top + sngOffset
        .Width = 0
        .Height = mlblBack.Height - (sngOffset * 2)
        .Caption = ""
        .BackColor = 8388608
        .BackStyle = 1
        .Visible = True
    End With

    ' set properties for caption label
    With mlblCaption
        .Left = mlblBack.Left + 2
        .Top = mlblBack.Top + 2
        .Width = mlblBack.Width - 4
        .Height = mlblBack.Height - 4
        .TextAlign = 2 'fmTextAlignCenter
        .BackStyle = 0 'fmBackStyleTransparent
        .Caption = "0%"
        .Visible = Not Me.HideCaption
        .ForeColor = 16777215   ' white
    End With
    'Stop

    Exit Sub

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Initialize", Erl
            Resume Next ' Resume at next line.
    End Select

End Sub

Private Sub Class_Terminate()

    On Error GoTo 0    ' Debug Mode

    On Error Resume Next
    mlblFront.Visible = False
    mlblCaption.Visible = False
    On Error GoTo 0    ' Debug Mode

    Exit Sub

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Class_Terminate", Erl
            Resume Next ' Resume at next line.
    End Select

End Sub

Public Property Get Max() As Double

    On Error GoTo 0    ' Debug Mode

    Max = mdblMax

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Max", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Let Max(ByVal dblMax As Double)

    On Error GoTo 0    ' Debug Mode

    mdblMax = dblMax

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Max", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Get Value() As Double

    On Error GoTo 0    ' Debug Mode

    Value = mdblVal

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Value", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Let Value(ByVal dblVal As Double)

    On Error GoTo 0    ' Debug Mode

    'update only if change is => 1%
    If (CInt(dblVal * (100 / mdblMax))) > (CInt(mdblVal * (100 / mdblMax))) Then
        mdblVal = dblVal
        Update
    Else
        mdblVal = dblVal
    End If

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Value", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Get IncrementSize() As Double

    On Error GoTo 0    ' Debug Mode

    IncrementSize = mdblIncSize

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "IncrementSize", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Let IncrementSize(ByVal dblSize As Double)

    On Error GoTo 0    ' Debug Mode

    mdblIncSize = dblSize

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "IncrementSize", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Get HideCaption() As Boolean

    On Error GoTo 0    ' Debug Mode

    HideCaption = mblnHideCap

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "HideCaption", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Public Property Let HideCaption(ByVal blnHide As Boolean)

    On Error GoTo 0    ' Debug Mode

    mblnHideCap = blnHide

    Exit Property

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "HideCaption", Erl
            Resume Next ' Resume at next line.
    End Select

End Property

Private Sub Update()

    On Error GoTo 0    ' Debug Mode

    Dim intPercent As Integer
    Dim dblWidth As Double
    'On Error Resume Next
    intPercent = mdblVal * (100 / mdblMax)
    dblWidth = mdblVal * (mdblFullWidth / mdblMax)
    mlblFront.Width = dblWidth
    mlblCaption.Caption = intPercent & "%"
    'mlblFront.Parent.Repaint    ' may not be needed

    ' Use white or black, depending on progress
    If Me.Value > (Me.Max / 2) Then
        mlblCaption.ForeColor = 16777215   ' white
    Else
        mlblCaption.ForeColor = 0  ' black
    End If

    If mblnNotSmooth Then
        If mdteLastUpdate <> Now Then
            ' update every second.
            DoEvents
            mdteLastUpdate = Now
        End If
    Else
        DoEvents
    End If

    Exit Sub

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Update", Erl
            Resume Next ' Resume at next line.
    End Select

End Sub

Public Sub Increment()

    On Error GoTo 0    ' Debug Mode

    Dim dblVal As Double
    dblVal = Me.Value
    If dblVal < Me.Max Then
        Me.Value = dblVal + 1
        'Call Update
    End If

    Exit Sub

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Increment", Erl
            Resume Next ' Resume at next line.
    End Select

End Sub

Public Sub Clear()

    On Error GoTo 0    ' Debug Mode

    Call Class_Terminate

    Exit Sub

ErrHandler:

    Select Case Err.Number
        Case Else
            LogErr Err, "clsLblProg", "Clear", Erl
            Resume Next ' Resume at next line.
    End Select

End Sub

Private Function ParentForm(ctlControl As Control) As String

    ' returns the name of the parent form
    Dim objParent As Object

    Set objParent = ctlControl

    Do While Not TypeOf objParent Is Form
       Set objParent = objParent.Parent
    Loop

    ' Now we should have the parent form
    ParentForm = objParent.Name

End Function

Public Property Get Smooth() As Boolean
    ' Display the progress bar smoothly.
    ' True by default, this property allows the call
    ' to doevents after every increment.
    ' If False, it will only update once per second.
    ' (This may increase speed for fast progresses.)
    '
    ' negative to set default to true
    Smooth = mblnNotSmooth
End Property

Public Property Let Smooth(ByVal IsSmooth As Boolean)
    mblnNotSmooth = Not IsSmooth
End Property

Private Sub LogErr(objErr, strMod, strProc, intLine)
    ' For future use.
End Sub
15
AdamsTips

Verwenden Sie den Befehl DoEvents , nachdem Sie die Fortschrittsleiste (acSysCmdUpdateMeter) aktualisiert haben.

Führen Sie DoEvents bei einer großen Anzahl von Datensätzen nur alle x-mal aus, da dies Ihre Anwendung etwas verlangsamt.

1
Jan

Aufgrund von Problemen mit der verfügbaren Steuerung habe ich aus zwei Rechtecken einen selbst entwickelten Fortschrittsbalken erstellt. Ein Rahmen und eine durchgehende Leiste, deren Größe mit dem Fortschreiten der Dinge angepasst wird. Das Fortschrittsrechteck vor dem Rand. Benutzen

If pbar Is Nothing Then
    Set pbar = New pBar_sub
    pbar.init Me.Progressbar_border, Me.ProgressBar_Bar
End If
pbar.value = 0
pbar.show
pbar.max = 145 ' number of interations
...
...
Do While Not recset.EOF
    count = count + 1
    pbar.value = count
'   get next 
    recset.MoveNext
Loop

Man kann der Statusleiste eine Statuszeile zuordnen, die angibt, welches Element verarbeitet wird. Mögen: 123. District SomeWhere, Verkaufsagent WomEver

======== Fortschrittsbalkenersatz pBar_sub ===============

Option Compare Database
Option Explicit

Dim position    As Long
Dim maximum     As Long
Dim increment   As Single
Dim border      As Object
Dim bar         As Object

Sub init(rect As Object, b As Object)
    Set border = rect
    Set bar = b
    bar.width = 0
    hide
End Sub
Sub hide()
    bar.visible = False
    border.visible = False
End Sub
Sub show()
    bar.visible = True
    border.visible = True
End Sub
Property Get Max() As Integer
    Max = maximum
End Property
Property Let Max(val As Integer)
    maximum = val
    increment = border.width / val
End Property
Property Get value() As Integer
    value = position
End Property
Property Let value(val As Integer)
    position = val
    bar.width = increment * value
End Property
1
jas0501

Fügen Sie einfach meinen Teil zu der obigen Sammlung für zukünftige Leser hinzu.

Wenn Sie nach weniger Code und vielleicht cooler Benutzeroberfläche suchen. Schauen Sie sich meine GitHub für Progressbar für VBA an enter image description here

eine anpassbare ein:

 enter image description here

Die DLL ist für MS-Access gedacht, sollte jedoch auf allen VBA-Plattformen mit geringfügigen Änderungen funktionieren. Alle Codes finden Sie in der Beispieldatenbank.

Dieses Projekt befindet sich derzeit in der Entwicklung und es werden nicht alle Fehler abgedeckt. Erwarten Sie also einige!

Sie sollten sich um Drittanbieter-DLLs sorgen, und wenn Sie es sind, können Sie vor dem Implementieren der DLL unbedingt vertrauenswürdige Online-Antivirenprogramme verwenden.

0
krish KM

Dies ist kein professioneller Weg, kann aber angewendet werden, wenn Sie es mögen. Wenn Sie ein Formular verwenden, können Sie ein kleines Textfeld an einer geeigneten Stelle mit der Farbe Grün verwenden.

Angenommen, das Textfeld Name ist TxtProcessing.
Eigenschaften können wie folgt sein.

Name : TxtProcessing
Visible : Yes
Back color : Green
Locked: Yes
Enter Key Behavior : Default

1) In Ihrem VB - Skript können Sie Me.TxtProcessing.BackColor = vbRed eingeben, der in Rot angezeigt wird und die Aufgabe in Process kennzeichnet.
2) Sie können alle Skripts schreiben
3) Zum Schluss können Sie Me.TxtProcessing.BackColor = vbGreen eingeben.

Me.TxtProcessing.BackColor = vbRed
Me.TxtProcessing.SetFocus
Me.Refresh

Your Code here.....

Me.TxtProcessing.BackColor = vbGreen
Me.TxtProcessing.SetFocus

:-) Komisch aber Zweck ist erreicht.

0
Shiva